From 061c169d277db5611a9d3ea8351f0d4d0d613b0a Mon Sep 17 00:00:00 2001
From: Benjamin Franzke <benjaminfranzke@googlemail.com>
Date: Fri, 23 Sep 2011 11:45:39 +0200
Subject: Rename message.h to message_list.h

---
 src/gen_message_list.sed | 24 ++++++++++++++++++++++++
 1 file changed, 24 insertions(+)
 create mode 100644 src/gen_message_list.sed

(limited to 'src/gen_message_list.sed')

diff --git a/src/gen_message_list.sed b/src/gen_message_list.sed
new file mode 100644
index 0000000..e1ffbeb
--- /dev/null
+++ b/src/gen_message_list.sed
@@ -0,0 +1,24 @@
+1 {
+i\
+#ifndef _MESSAGE_LIST_H_ \
+#define _MESSAGE_LIST_H_ \
+\
+#define MUMBLE_MSGS \\
+}
+
+# Backup original message name
+h
+# Prefix uppercase characters that follow a lowercase one
+s/\([a-z]\)\([A-Z]\)/\1_\2/g
+# Lowercase uppercase characters
+y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/
+# Append backup to lowercase underscored message
+G
+# Put template macro around (delete newline between both msgs, swap order)
+s/^\(.*\)\n\(.*\)$/\tMUMBLE_MSG(\2, \1) \\/
+
+$ {
+a\
+\
+#endif /* _MESSAGE_LIST_H_ */
+}
-- 
cgit