From 29cf3a93cc8a67edcf307ba944bb3d5f90a3d55a Mon Sep 17 00:00:00 2001
From: Jelmer Vernooij <jelmer@samba.org>
Date: Wed, 21 Nov 2007 13:22:54 +0100
Subject: r26089: Move python detection to a separate file, and don't make it
 an error if it isn't available. (This used to be commit
 4e7709379de2fb9bf1eafd9ee9cbe10a0e6df51e)

---
 source4/scripting/python/config.m4 | 117 +++++++++++++++++++++++++++++++++++++
 1 file changed, 117 insertions(+)
 create mode 100644 source4/scripting/python/config.m4

(limited to 'source4/scripting')

diff --git a/source4/scripting/python/config.m4 b/source4/scripting/python/config.m4
new file mode 100644
index 0000000000..36bf8a6049
--- /dev/null
+++ b/source4/scripting/python/config.m4
@@ -0,0 +1,117 @@
+AC_ARG_VAR([PYTHON_VERSION],[The installed Python
+	version to use, for example '2.3'. This string 
+	will be appended to the Python interpreter
+	canonical name.])
+
+AC_PATH_PROG([PYTHON],[python[$PYTHON_VERSION]])
+if test -z "$PYTHON"; then
+	AC_MSG_WARN([No python found])
+	SMB_ENABLE(LIBPYTHON,NO)
+else
+	SMB_ENABLE(LIBPYTHON,YES)
+fi
+
+#
+# Check for a version of Python >= 2.1.0
+#
+AC_MSG_CHECKING([for a version of Python >= '2.1.0'])
+ac_supports_python_ver=`$PYTHON -c "import sys, string; \
+	ver = string.split(sys.version)[[0]]; \
+	print ver >= '2.1.0'"`
+if test "$ac_supports_python_ver" != "True"; then
+	AC_MSG_RESULT([no])
+	AC_MSG_ERROR([No recent version of python found])
+else 
+	AC_MSG_RESULT([yes])
+fi
+
+#
+# Check if you have distutils, else fail
+#
+AC_MSG_CHECKING([for the distutils Python package])
+ac_distutils_result=`$PYTHON -c "import distutils" 2>&1`
+if test -z "$ac_distutils_result"; then
+	AC_MSG_RESULT([yes])
+else
+	AC_MSG_RESULT([no])
+	AC_MSG_ERROR([distutils not available])
+fi
+
+#
+# Check for Python include path
+#
+AC_MSG_CHECKING([for Python include path])
+if test -z "$PYTHON_CPPFLAGS"; then
+	python_path=`$PYTHON -c "import distutils.sysconfig; \
+			print distutils.sysconfig.get_python_inc();"`
+	if test -n "${python_path}"; then
+		python_path="-I$python_path"
+	fi
+	PYTHON_CPPFLAGS=$python_path
+fi
+AC_MSG_RESULT([$PYTHON_CPPFLAGS])
+AC_SUBST([PYTHON_CPPFLAGS])
+
+#
+# Check for Python library path
+#
+AC_MSG_CHECKING([for Python library path])
+if test -z "$PYTHON_LDFLAGS"; then
+	# (makes two attempts to ensure we've got a version number
+	# from the interpreter)
+	py_version=`$PYTHON -c "from distutils.sysconfig import *; \
+		from string import join; \
+		print join(get_config_vars('VERSION'))"`
+	if test "$py_version" == "[None]"; then
+		if test -n "$PYTHON_VERSION"; then
+			py_version=$PYTHON_VERSION
+		else
+			py_version=`$PYTHON -c "import sys; \
+				print sys.version[[:3]]"`
+		fi
+	fi
+
+	PYTHON_LDFLAGS=`$PYTHON -c "from distutils.sysconfig import *; \
+		from string import join; \
+		print '-L' + get_python_lib(0,1), \
+			'-lpython';"`$py_version
+fi		
+AC_MSG_RESULT([$PYTHON_LDFLAGS])
+AC_SUBST([PYTHON_LDFLAGS])
+
+#
+# Check for site packages
+#
+AC_MSG_CHECKING([for Python site-packages path])
+if test -z "$PYTHON_SITE_PKG"; then
+	PYTHON_SITE_PKG=`$PYTHON -c "import distutils.sysconfig; \
+			print distutils.sysconfig.get_python_lib(0,0);"`
+fi
+AC_MSG_RESULT([$PYTHON_SITE_PKG])
+AC_SUBST([PYTHON_SITE_PKG])
+
+#
+# libraries which must be linked in when embedding
+#
+AC_MSG_CHECKING(python extra libraries)
+if test -z "$PYTHON_EXTRA_LIBS"; then
+   PYTHON_EXTRA_LIBS=`$PYTHON -c "import distutils.sysconfig; \
+			conf = distutils.sysconfig.get_config_var; \
+			print conf('LOCALMODLIBS'), conf('LIBS')"`
+fi
+AC_MSG_RESULT([$PYTHON_EXTRA_LIBS])
+AC_SUBST(PYTHON_EXTRA_LIBS)
+
+#
+# linking flags needed when embedding
+#
+AC_MSG_CHECKING(python extra linking flags)
+if test -z "$PYTHON_EXTRA_LDFLAGS"; then
+	PYTHON_EXTRA_LDFLAGS=`$PYTHON -c "import distutils.sysconfig; \
+		conf = distutils.sysconfig.get_config_var; \
+		print conf('LINKFORSHARED')"`
+fi
+AC_MSG_RESULT([$PYTHON_EXTRA_LDFLAGS])
+AC_SUBST(PYTHON_EXTRA_LDFLAGS)
+
+SMB_EXT_LIB(LIBPYTHON, [$PYTHON_LDFLAGS], [$PYTHON_CPPFLAGS])
-- 
cgit