docs/xslt/sambadoc2pearson.xsl


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98

<?xml version='1.0'?>
<!-- 
	Convert DocBook to XML validating against the Pearson DTD

	(C) Jelmer Vernooij <jelmer@samba.org>			2004
-->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	xmlns:doc="http://nwalsh.com/xsl/documentation/1.0"
	exclude-result-prefixes="doc"
	version="1.1" >

	<xsl:import href="docbook2pearson.xsl"/>

	<xsl:strip-space elements="smbconfoption smbconfsection"/>

	<xsl:template match="smbfile">
		<xsl:apply-templates/>
	</xsl:template>

	<xsl:template match="smbconfexample/smbconfsection|smbconfblock/smbconfsection">
		<xsl:text>&#10;</xsl:text>
		<xsl:value-of select="."/><xsl:text>&#10;</xsl:text>
	</xsl:template>

	<xsl:template match="smbconfexample/smbconfoption|smbconfblock/smbconfoption">
		<xsl:text>	</xsl:text><xsl:value-of select="name"/><xsl:text> = </xsl:text><xsl:value-of select="value"/><xsl:text>&#10;</xsl:text>
	</xsl:template>

	<xsl:template match="smbconfexample">
	   <listing>
		   <xsl:call-template name="transform.id.attribute"/>
		   <xsl:if test="title != ''">
			   <description><xsl:value-of select="title"/></description>
		   </xsl:if>
		   <listingcode>
			   <xsl:for-each select="smbconfoption|smbconfsection|smbconfcomment">
			   	<xsl:apply-templates select="."/>
			   </xsl:for-each>
		   </listingcode>
		</listing>
	</xsl:template>

	<xsl:template match="smbconfblock">
		<xsl:call-template name="transform.id.attribute"/>
		<listingcode>
		<xsl:apply-templates/>
		</listingcode>
	</xsl:template>

	<xsl:template match="image">
		<figure>
			<xsl:call-template name="transform.id.attribute"/>
			<description><xsl:value-of select="imagedescription"/></description>
			<figureref>
				<xsl:attribute name="fileref">
					<xsl:value-of select="imagefile"/>
				</xsl:attribute>
				<xsl:if test="@scale != ''">
					<xsl:attribute name="scale">
						<xsl:value-of select="@scale"/>
					</xsl:attribute>
				</xsl:if>
			</figureref>
		</figure>
	</xsl:template>

	<xsl:template match="smbconfexample/smbconfcomment|smbconfblock/smbconfcomment">
		<xsl:text># </xsl:text><xsl:value-of select="text()"/><xsl:text>&#10;</xsl:text>
	</xsl:template>

	<xsl:template match="smbconfexample/member|smbconfblock/member">
		<xsl:value-of select="text()"/><xsl:text>&#10;</xsl:text>
		<xsl:message><xsl:text>Encountered &lt;member&gt; element inside of smbconfexample/smbconfblock!</xsl:text></xsl:message>
	</xsl:template>

	<xsl:template match="filterline">
		<code><xsl:apply-templates/></code>
	</xsl:template>

	<xsl:template match="smbconfoption">
		<code><xsl:value-of select="name"/></code>
		<xsl:if test="value != ''">
			<xsl:text> = </xsl:text>
			<xsl:value-of select="value"/>
		</xsl:if>
		<xsl:text>&#10;</xsl:text>
	</xsl:template>

	<xsl:template match="smbconfsection">
		<code><xsl:apply-templates/></code>
	</xsl:template>

	<xsl:template match="ntgroup|ntuser">
		<em><xsl:apply-templates/></em>
	</xsl:template>
	<!-- translator -->

</xsl:stylesheet>