1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
AC_CACHE_CHECK([for broken readdir],libreplace_READDIR_NEEDED,[
AC_TRY_RUN([
#define test_readdir_os2_delete main
#include "$libreplacedir/test/os2_delete.c"],
[libreplace_READDIR_NEEDED=no],
[libreplace_READDIR_NEEDED=yes],
[libreplace_READDIR_NEEDED="assuming not"])
])
#
# try to replace with getdents() if needed
#
if test x"$libreplace_READDIR_NEEDED" = x"yes"; then
AC_CHECK_FUNCS(getdents)
AC_CACHE_CHECK([for replacing readdir using getdents()],libreplace_READDIR_GETDENTS,[
AC_TRY_RUN([
#define _LIBREPLACE_REPLACE_H
#include "$libreplacedir/repdir_getdents.c"
#define test_readdir_os2_delete main
#include "$libreplacedir/test/os2_delete.c"],
[libreplace_READDIR_GETDENTS=yes],
[libreplace_READDIR_GETDENTS=no])
])
fi
if test x"$libreplace_READDIR_GETDENTS" = x"yes"; then
AC_DEFINE(REPLACE_READDIR,1,[replace readdir])
AC_DEFINE(REPLACE_READDIR_GETDENTS,1,[replace readdir using getdents()])
LIBREPLACEOBJ="${LIBREPLACEOBJ} repdir_getdents.o"
libreplace_READDIR_NEEDED=no
fi
#
# try to replace with getdirentries() if needed
#
if test x"$libreplace_READDIR_NEEDED" = x"yes"; then
AC_CHECK_FUNCS(getdirentries)
AC_VERIFY_C_PROTOTYPE([long telldir(const DIR *dir)],
[
return 0;
],[
AC_DEFINE(TELLDIR_TAKES_CONST_DIR, 1, [Whether telldir takes a const pointer])
],[],[
#include <dirent.h>
])
AC_VERIFY_C_PROTOTYPE([int seekdir(DIR *dir, long ofs)],
[
return 0;
],[
AC_DEFINE(SEEKDIR_RETURNS_INT, 1, [Whether seekdir returns an int])
],[],[
#include <dirent.h>
])
AC_CACHE_CHECK([for replacing readdir using getdirentries()],libreplace_READDIR_GETDIRENTRIES,[
AC_TRY_RUN([
#define _LIBREPLACE_REPLACE_H
#include "$libreplacedir/repdir_getdirentries.c"
#define test_readdir_os2_delete main
#include "$libreplacedir/test/os2_delete.c"],
[libreplace_READDIR_GETDIRENTRIES=yes],
[libreplace_READDIR_GETDIRENTRIES=no])
])
fi
if test x"$libreplace_READDIR_GETDIRENTRIES" = x"yes"; then
AC_DEFINE(REPLACE_READDIR,1,[replace readdir])
AC_DEFINE(REPLACE_READDIR_GETDIRENTRIES,1,[replace readdir using getdirentries()])
LIBREPLACEOBJ="${LIBREPLACEOBJ} repdir_getdirentries.o"
libreplace_READDIR_NEEDED=no
fi
AC_MSG_CHECKING([a usable readdir()])
if test x"$libreplace_READDIR_NEEDED" = x"yes"; then
AC_MSG_RESULT(no)
AC_MSG_WARN([the provided readdir() is broken])
else
AC_MSG_RESULT(yes)
fi
|
